IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[sp_CleanFrlloRecipeProcess]') AND type in (N'P', N'PC'))
DROP PROCEDURE [dbo].[sp_CleanFrlloRecipeProcess]
GO
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[rds].[sp_CleanFrlloRecipeProcess]') AND type in (N'P', N'PC'))
DROP PROCEDURE [rds].[sp_CleanFrlloRecipeProcess]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:      Vitacore (с) Anatoliy
-- Create date: 2021 05 25
-- Description: Выгрузка данных в ФРЛЛО
-- =============================================
CREATE PROCEDURE [rds].[sp_CleanFrlloRecipeProcess]
    @ExportId uniqueidentifier
AS
BEGIN

DECLARE @NUM INT = 1000

CREATE TABLE #TMP_OBJ(
	 ID UNIQUEIDENTIFIER NOT NULL UNIQUE
	,NUM INT IDENTITY(1,1)
)

	INSERT INTO #TMP_OBJ(ID)
	SELECT DISTINCT ExportFrlloRecipeDataID
	FROM RDS.T_EXPORT_FRLLO_RECIPE_DATA fed  
	WHERE fed.ExportFrlloRecipe = @ExportId

WHILE EXISTS(SELECT TOP 1 1 FROM #TMP_OBJ)
	BEGIN

		UPDATE fed
			SET 
				 fed.FrlloId = NULL
				,fed.FrlloStatus = NULL
				,fed.RegNum = NULL
				,fed.FrlloError = NULL
		FROM RDS.T_EXPORT_FRLLO_RECIPE_DATA fed
		WHERE EXISTS(SELECT 1 FROM #TMP_OBJ T WHERE T.ID = fed.ExportFrlloRecipeDataID AND T.NUM <= @NUM)
		and COALESCE(fed.FrlloStatus, 1) <> 1 and fed.ExportFrlloRecipe = @ExportId

		DELETE #TMP_OBJ
		WHERE NUM <= @NUM
		
		SET @NUM = @NUM + 1000

	END
END